.MCALL	.MODULE
.MODULE	VTCHEK,VERSION=07,COMMENT=<Environment check code for VTCOM>

; Copyright (c) 1998 by Mentec, Inc., Nashua, NH.
; All rights reserved
;
; This software is furnished under a license for use only on a
; single computer system and  may  be  copied  only  with  the
; inclusion of the above copyright notice.  This software,  or
; any other copies thereof, may not be provided  or  otherwise
; made available to any other person except for  use  on  such
; system and to one who agrees to these license  terms.  Title
; to  and  ownership of the software shall at all times remain
; in Mentec, Inc.
;
; The information in this document is subject to change without
; notice and should not be construed as a commitment by Digital
; Equipment Corporation, or Mentec, Inc.
;
; Digital and Mentec  assume  no  responsibility for the use or
; reliability of its software on equipment which is not supplied
; by Digital  or Mentec,  and listed  in the  Software  Product
; Description.
	.SBTTL	EDIT HISTORY

;+
;
; V01 (000) 22-Jan-84	Initial coding. This routine added for XM
;	MBG		check with VTCOM.REL
;
; V05 (001) 23-Jan-84	Ready for release
;
; V05 (002) 24-Jan-84	Audit information
;	MBG
;
; Y05 (003) 21-Dec-84	Check added for timer support under SJ.
;	MBG
;
; Y05 (004) 03-Mar-85	Moved area for extra queue elements into this
;	MBG		module, main code references it.
;
; Y05 (005)		???
;
; Y05 (006) 01-Nov-1990	bracket error messages with ;+/;ERROR/.../;-
;
; (007) 04-JAN-91 MBG	Removed reference to FBMON$, code should always
;			verify that timer support is available.
;
;-
	.SBTTL	DEFINITIONS

; RT-11 System macros we'll be using

	.MCALL	.GVAL,	.PRINT,	.EXIT

; RMON Fixed Offset Area

	CONFIG	= 300			;Configuration word
		KT11$	= 010000 ;Mapped monitor is running (XM)
;;;		FBMON$	= 000001 ;Running FB or XM monitor
	SYSGEN	= 372			;Sysgen features word
		TIMER$	= 002000 ;SJ timer support

; Feature Tests

	.IIF NDF FT.MIN	FT.MIN	= 0	;Expert mode error messages (=1)

; Print error message at terminal in the standard form
;	'?facility-severity-text'

	.MACRO	ERROR.	MESADR
		JSR	R0,PRTMES
		 .WORD	MESADR
	.ENDM

; Define an error message

	.MACRO	ERRTXT	SEVER,EXPERT,TEXT,CR=YES
	..MASK = 0
	..FLAG = 0
	.IRPC XXX,<IWEFU>
	 .IF EQ ..FLAG
	  .IF IDN SEVER,XXX
		..FLAG = 1
	  .IFF
	   .IIF EQ ..MASK ..MASK = 1
		..MASK = ..MASK*2
	  .ENDC ;IDN SEVER,XX
	 .ENDC ;EQ ..FLAG
	.ENDR
	.IF NE ..FLAG
		.NLIST	BEX
		.BYTE	..MASK
		.BYTE	''SEVER
	 .IF EQ FT.MIN
		.ASCII	|'TEXT' |<200>
	 .IFF
		.ASCII	|'EXPERT' |<200>
	 .ENDC ;EQ FT.MIN
	 .IF IDN CR,YES
		. = .-2
		.BYTE	0
	 .ENDC ;IDN CR,YES
		.LIST	BEX
	.IFF
		.ERROR	;INVALID SEVERITY ''SEVER''
	.ENDC ;NE ..FLAG
	.ENDM
	.SBTTL	XMCHEK	- XM check routine for VTCOM (REL version)

;+
;
; XMCHEK
;	Checks if VTCOM.REL is running under XM and if so, prints
;	a warning message
;
; CALL
;	R2 -> EMT area for use
;
;-

	.GLOBL	XMCHEK,	PRTMES

XMCHEK:	.GVAL	R2,#CONFIG		;Get contents of configuration word
	BIT	#KT11$,R0		;Running under XM monitor?
	BEQ	10$			;Nope...
;+
;ERROR
	ERROR.	M.XMCK			;Yes, let them know that there's
;-
					; a better version to run
10$:	RETURN
	.SBTTL	SJTMCK	- Check for SJ timer support

;+
;
; SJTMCK
;	Verifies that VTCOM is running under a monitor with timer
;	support and if not, reports that it can't run and exits.
;
; CALL
;	R2 -> EMT area for use
;
;-

	.GLOBL	SJTMCK,	PRTMES

SJTMCK:
;;;	.GVAL	R2,#CONFIG		;Get contents of configuration word
;;;	BIT	#FBMON$,R0		;Running under FB/XM?
;;;	BNE	10$			;Yep...
	.GVAL	R2,#SYSGEN		;Get the sysgen features word
	BIT	#TIMER$,R0		;Does it have timer support?
	BNE	10$			;Yep...
;+
;ERROR
	ERROR.	M.SJTM			;Nope, let them know that we can't run
;-
	.EXIT				; and go away

10$:	RETURN
	.SBTTL	Messages

;+
;ERROR
M.XMCK:	ERRTXT	W,VER,<Use XM version, VTCOM.SAV>
M.SJTM:	ERRTXT	F,TSR,<Timer support required>
;-
	.EVEN
	.SBTTL	Impure data area

QELEM::	.BLKW	10.*10.

	.END