.MCALL .MODULE
.MODULE	RESOPT,VERSION=03,COMMENT=<RESORC /O>,IDENT=NO

; Copyright (c) 1998 by Mentec, Inc., Nashua, NH.
; All rights reserved
;
; This software is furnished under a license for use only on a
; single computer system and  may  be  copied  only  with  the
; inclusion of the above copyright notice.  This software,  or
; any other copies thereof, may not be provided  or  otherwise
; made available to any other person except for  use  on  such
; system and to one who agrees to these license  terms.  Title
; to  and  ownership of the software shall at all times remain
; in Mentec, Inc.
;
; The information in this document is subject to change without
; notice and should not be construed as a commitment by Digital
; Equipment Corporation, or Mentec, Inc.
;
; Digital and Mentec  assume  no  responsibility for the use or
; reliability of its software on equipment which is not supplied
; by Digital  or Mentec,  and listed  in the  Software  Product
; Description.
;++
;
;	Edit	Who	Date		Description of modification
;	----	---	----		---------------------------
;	001	WLD	16-NOV-90	Eliminate reference to MONSF
;					(FBMON$).
;--
; Edit History:
; 001	George Stevens	Overlaid version of RESORC.  Created from RESORC
;			Version 97
;
; (002) 16-Jul-90 	Added support for reporting presence of
;	MBG		multi-terminal handler hooks support.
	.NLIST
	.INCLUDE /SRC:RESPFX.MAC/
	.LIST
.SBTTL	OPTGEN - List the SYSGEN options

;+
; This routine displays the SYSGEN options enabled.
;-
	ORIGIN	RESOPT

	.ENABL	LSB

OPTGEN::.PRINT	#CRLF		;Print a <CR><LF>
	MOV	$SYSGN(R5),R1	;Get the sysgen word
	BIC	#SY.MMU,R1	;Clear out the memory management bit
	BNE	10$		;Branch if any options set
	PRINT	NSO,<No SYSGEN options enabled>
	BR	90$		;And branch to return

10$:	BIT	#SY.TIM,R1	;Device time-out support?
	BEQ	20$		;Branch if not
	PRINT	TIMER,<Device I/O time-out support>

20$:	BIT	#SY.EL,R1	;Error logging?
	BEQ	30$		;Branch if not
	PRINT	ELOG,<Error logging support>

30$:	BIT	#SY.MTT,R1	;Multi-terminal?
	BEQ	40$		;Branch if not
	PRINT	MTTY,<Multi-terminal support>

40$:	BIT	#SY.MPR,R1	;Memory parity support?
	BEQ	50$		;Branch if not
	PRINT	MEMPAR,<Memory parity support>

50$:	CMPB	#1,$JOBS(R5)	;Is monitor RT11SB?
	BNE	60$		;BR if not.
	BIT	#SY.MMU,$SYSGN(R5)
	BNE	60$		;BR if not.
	BIT	#SY.MKT,R1	;SB timer support?
	BEQ	60$		;Branch if not
	PRINT	SBTIME,<SB timer support>

60$:	BIT	#SY.SJB,R1	;SYSTEM JOBBING?
	BEQ	70$		;Branch if not
	PRINT	SYJB,<System job support>

70$:	BIT	#C2.GSC,$CNFG2(R5)	;Global .SCCA?
	BEQ	80$		;Branch if not
	PRINT	GBLSCA,<Global .SCCA support>

80$:	BIT	#SY.FPU,R1	;FPU support?
	BEQ	90$		;Branch if not
	PRINT	FPU,<FPU support>

90$:	BIT	#CF3.64,$CNFG3(R5)	;64 unit support?
	BEQ	100$		;Branch if not
	PRINT	UNIT64,<Extended unit support>

100$:	TST	$THKPT(R5)		;Terminal hooks support available?
	BEQ	105$			;Nope...
	PRINT	THOOKS,<Multi-terminal handler hooks support>

105$:
;	.DSTAT	#DSAREA+1,#CADEV ; Get CA handlers status
;	BCS	110$		; Branch if error - CA not installed
;	TST	DSAREA+4	; Is CA loaded?
;	BNE	120$		; Branch if so
;110$:	PRINT	DSCASH,<Disk CACHE disabled>
;	BR	130$
;
;120$:	PRINT	ENCASH,<Disk CACHE enabled>

130$:	BIT	#CF3.US,$CNFG3(R5) ; Is UMR support enabled?
	BEQ	160$		   ; Branch if not
	BIT	#C2.PC!C2.BUS,$CNFG2(R5) ; Is this a UNIBUS machine?
	BNE	160$		; NO, Need UNIBUS for UMR
	PRINT	UMRPFX,^%UNIBUS mapping \<200>\%
	.TRPSET	#AREA,#TRP1	; Catch traps to 4 or 10
	TST	@#UMRCSR	; Is UMR present?
	NOP			; - Delay
	BCS	150$		; Branch if no UMR
	BIT	#CF3.UA,$CNFG3(R5) ; Is UMR active?
	BEQ	140$		; Branch if UMR not active
	PRINT	UMRENA,<enabled>
	BR	160$

140$:	PRINT	UMRDIS,<disabled>
	BR	160$

150$:	PRINT	NOUMR,<unavailable>

160$:
	RETURN	

	.DSABL	LSB

	.END