.MCALL	.MODULE
.MODULE	 PURGE,VERSION=04,COMMENT=<PURGE/SYSLIB>,IDENT=No,LIB=YES

; Copyright (c) 1998 by Mentec, Inc., Nashua, NH.
; All rights reserved
;
; This software is furnished under a license for use only on a
; single computer system and  may  be  copied  only  with  the
; inclusion of the above copyright notice.  This software,  or
; any other copies thereof, may not be provided  or  otherwise
; made available to any other person except for  use  on  such
; system and to one who agrees to these license  terms.  Title
; to  and  ownership of the software shall at all times remain
; in Mentec, Inc.
;
; The information in this document is subject to change without
; notice and should not be construed as a commitment by Digital
; Equipment Corporation, or Mentec, Inc.
;
; Digital and Mentec  assume  no  responsibility for the use or
; reliability of its software on equipment which is not supplied
; by Digital  or Mentec,  and listed  in the  Software  Product
; Description.
	.SBTTL	Module Declarations

	.NLIST
	.ENABL	LC
	.DSABL	GBL
	.NLIST	CND
	.LIST
; ++
; FACILITY:
;
;    RT-11 System Subroutine Library
;
; ENVIRONMENT:
;
;    This routine can be used in any job running in a single-job
;    or multi-job environment.  It uses "TRAP" to provide  error
;    processing.
;
; INCLUDE FILES:
;

	; SYSMAC.SML		; RT-11 system macro library.

	.MCALL	.PURGE		; PURGE programmed request.

;
; EXTERNAL REFERENCES:
;

	.GLOBL	$NXVAL		; Entry point to next value routine
	.GLOBL	$SYSLB		; Include system library work area
	.WEAK	$MSARG		; Trap code for missing argument

	.SBTTL	PURGE - Fortran-callable Routine

; ++
; FUNCTIONAL DESCRIPTION:
;
;    The PURGE routine deactivates a specified channel without performing
;    an ISAVES, CLOSEC, or ICLOSE.
;    
; CALLING SEQUENCE:
;
;    CALL PURGE( chan )
;
; INPUT PARAMETERS:
;
;    R5	     -	address of PURGE's argument block
;
;    0(R5)   -	argument count of PURGE call
;    2(R5)   -	address of number of channel to purge
;
; --

	.PSECT	SYS$I

PURGE::	MOV	(R5)+,R4	; R4 <- argument count

	CALL	$NXVAL		; Get 'chan' argument
	BCS	ERR		; If CS, error - 'chan' wasn't supplied
	MOV	R0,R3		; R3 <- number of channel to purge; isolates
				; channel # in low byte of 'chan' for .PURGE
	.PURGE	R3		; Purge caller-specified channel
	RETURN	
	
ERR:	TRAP	$MSARG		; handle any  missing arguments in call
	RETURN			

	.END