.MCALL	.MODULE
.MODULE	LOOKUP,VERSION=06,COMMENT=<LOOKUP/SYSLIB>,IDENT=No,LIB=Yes

; Copyright (c) 1998 by Mentec, Inc., Nashua, NH.
; All rights reserved
;
; This software is furnished under a license for use only on a
; single computer system and  may  be  copied  only  with  the
; inclusion of the above copyright notice.  This software,  or
; any other copies thereof, may not be provided  or  otherwise
; made available to any other person except for  use  on  such
; system and to one who agrees to these license  terms.  Title
; to  and  ownership of the software shall at all times remain
; in Mentec, Inc.
;
; The information in this document is subject to change without
; notice and should not be construed as a commitment by Digital
; Equipment Corporation, or Mentec, Inc.
;
; Digital and Mentec  assume  no  responsibility for the use or
; reliability of its software on equipment which is not supplied
; by Digital  or Mentec,  and listed  in the  Software  Product
; Description.
	.SBTTL	Module Declarations

	.NLIST
	.ENABL	LC
	.DSABL	GBL
	.NLIST	CND
	.LIST
; ++
; FACILITY:
;
;    RT-11 System Subroutine Library
;
; ENVIRONMENT:
;
;    This routine can be used by any job running in a single-job
;    or multi-job environment.  It uses "TRAP" to provide  error
;    processing.
;
; INCLUDE FILES:
;

	; SYSMAC.SML		; RT-11 system macro library.

	.MCALL	.LOOKUP		; LOOKUP programmed request.

;
; EXTERNAL REFERENCES:
;
	.GLOBL	$ERRM0		; Entry point to EMT error conversion routine.
	.GLOBL	$NXADR		; Entry point to next address routine.
	.GLOBL	$NXVAL		; Entry point to next value routine.
	.GLOBL	$SYSLB		; Include system library work area.
	.WEAK	$MSARG		; Trap code for missing argument
	.SBTTL	LOOKUP - Fortran-callable Routine

; ++
; FUNCTIONAL DESCRIPTION:
;
;    The LOOKUP function  associates a  specified  channel  with a device
;    and/or a file for the purpose of performing i/o operations.
;    
; CALLING SEQUENCE:
;
;    i = LOOKUP( chan, dblk [,seqnum] )
;
;    i = LOOKUP( chan, jobdes )
;
; INPUT PARAMETERS:
;
;    R5	     -	address of LOOKUP's argument block
;
;    0(R5)   -	argument count of LOOKUP call
;    2(R5)   -  address of number of channel to associate with the file
;    4(R5)   -  address of four-word Radix-50 descriptor of file or address
;		of four-word descriptor of job (messages sent or received)
;    6(R5)   -  address of file sequence no. for magtape operations;
;		if argument is omitted, value is defaulted to 0
;
; RETURNED FUNCTION VALUE:
; 
; i =   +n	no errors on lookup (file-structured), n equals number of
;		blocks in file just opened
;   =    0	no errors on lookup (non-file-structured or magtape)
;   =   -1	channel ('chan') is already in use
;   =   -2	file specified was not found or no such job exists
;   =   -3	device in use
;   =   -6	illegal argument error with non-file-structured volume
;   =   -7	invalid unit number specil directory device
;
; --

	.PSECT	SYS$I

LOOKUP::			
	MOV	(R5)+,R4	; R4(low byte) <- argument count.
	CALL	$NXVAL		; Get 'chan' argument
	BCS	ERR		; If CS, error:'chan' argument wasn't supplied

	MOV	R0,R1		; R1 <- channel no. to use for .LOOKUP
	CALL	$NXADR		; Get -> 'dblk' argument
	BCS	ERR		; If CS, error:'dblk' argument wasn't supplied

	MOV	R0,R2		; R2 <- address of descriptor for .LOOKUP
	CLR	R0		; Default 'seqnum' to 0 - in case it's omitted
	CALL	$NXVAL		; Get 'seqnum' argument
	MOV	R0,-(SP)	; Store 'seqnum' in LOOKUP's argument block
	MOV	R2,-(SP)	; Store 'dblk' in LOOKUP's argumnent block
	MOV	R1,-(SP)	; Store 'chan' in LOOKUP's arguments block
	.LOOKUP	SP		; Lookup specified job/file/device
	BCC	10$		; IF successful lookup, preserve value in R0
	CALL	$ERRM0		; Get and convert any errors (status in R0)
10$:	ADD	#6,SP		; Purge stack of argument block
	RETURN			; Return to caller with status in R0

ERR:	TRAP	$MSARG		; Handle any missing arguments in call
	RETURN			

	.END