.MCALL	.MODULE
.MODULE ISPCPS,VERSION=02,COMMENT=<ISPCPS/SYSLIB>,IDENT=NO,LIB=YES

; Copyright (c) 1998 by Mentec, Inc., Nashua, NH.
; All rights reserved
;
; This software is furnished under a license for use only on a
; single computer system and  may  be  copied  only  with  the
; inclusion of the above copyright notice.  This software,  or
; any other copies thereof, may not be provided  or  otherwise
; made available to any other person except for  use  on  such
; system and to one who agrees to these license  terms.  Title
; to  and  ownership of the software shall at all times remain
; in Mentec, Inc.
;
; The information in this document is subject to change without
; notice and should not be construed as a commitment by Digital
; Equipment Corporation, or Mentec, Inc.
;
; Digital and Mentec  assume  no  responsibility for the use or
; reliability of its software on equipment which is not supplied
; by Digital  or Mentec,  and listed  in the  Software  Product
; Description.
	.SBTTL	Module Declarations

	.NLIST
	.ENABL	LC
	.DSABL	GBL
	.NLIST	CND
	.LIST
; ++
; FACILITY:
;
;    RT-11 System Subroutine Library
;
; ENVIRONMENT:
;
;    This routine can be used by any job running in a single-job
;    or multi-job environment. 
;
; INCLUDE FILES:
;
	; SYSMAC.MAC		; RT-11 system macro library

	.MCALL	.SPCPS		; SPCPS programmed request

; EXTERNAL REFERENCES:
;
     
	.GLOBL	$NXADR		; Entry point to next address routine
	.GLOBL	$SYSLB		; Include system library work area
	.GLOBL	$ERRM0
	.GLOBL	$ARGER
	.SBTTL	ISPCPS - Fortran-callable Routine
;
; ++
; FUNCTIONAL DESCRIPTION:
;
; The ISPCPS function allows a program's completion routine to change the
; flow of control of the mainline code
;    
; CALLING SEQUENCE:
;
;       Form: i =  ISPCPS (addr)
;
; INPUT PARAMETERS:
;
;    R5	     -	address of ISPCPS argument block
;
;    0(R5)   -  argument count of ISPCPS call
;    2(R5)   -  address of the three-word area in user memory that contains 
;       the new mainline PC, and that to contain the old mainline PC and PS
;
; RETURNED FUNCTION VALUE:
;
; i =   0  - Normal return 
;      -1  - ISPCPS was issued from mainline code rather than a completion 
;	     routine
;      -2  - a previous ISPCPS call is outstanding
; --

	.PSECT  SYS$I,I

SPCPS::
ISPCPS::
	MOV	(R5)+,R4	;R4(low byte) <- argument count
	CALL	$NXADR		;get addr argument
	BCS	10$		;required arg missing
	MOV	R0,-(SP)	;store addr in ISPCPS argumernt block
	TST	-(SP)		;allocate remaining space
	.SPCPS	SP		
	BIT	(SP)+,(SP)+	;*C* align stack
	CALLR	$ERRM0		;

10$:	MOV     #$ARGER,R0      ;Required arg missing
        RETURN

	.END