.MCALL	.MODULE
.MODULE	INDTIM,VERSION=07,COMMENT=<Time processor, Enable/Disable>

; Copyright (c) 1998 by Mentec, Inc., Nashua, NH.
; All rights reserved
;
; This software is furnished under a license for use only on a
; single computer system and  may  be  copied  only  with  the
; inclusion of the above copyright notice.  This software,  or
; any other copies thereof, may not be provided  or  otherwise
; made available to any other person except for  use  on  such
; system and to one who agrees to these license  terms.  Title
; to  and  ownership of the software shall at all times remain
; in Mentec, Inc.
;
; The information in this document is subject to change without
; notice and should not be construed as a commitment by Digital
; Equipment Corporation, or Mentec, Inc.
;
; Digital and Mentec  assume  no  responsibility for the use or
; reliability of its software on equipment which is not supplied
; by Digital  or Mentec,  and listed  in the  Software  Product
; Description.
.ENABL	GBL,LC

	.SBTTL	Macro definitions and local data

;+
;System macro calls.
;-

	.MCALL	.TWAIT, .PRINT, .RCTRLO
	.MCALL	DEFIN$, RT5DF$

DEFIN$				;Definitions for IND files
RT5DF$				;Define RT definitions

	OPSECT	INDTIM

;+
;Local data.
;-

	.NLIST	BEX
CONMSG:	.ASCIZ	/...Continuing/
DELMSG:	.ASCIZ	/Delaying.../
	.EVEN
	.LIST	BEX
	.SBTTL	DELAY - Delay processing

;+
;DELAY
;This rountine is entered when a .DELAY directive is encountered.  R0 points
;the the command buffer and is destroyed upon completion of this routine.
;-

	.ENABL	LSB

DELAY::	CALL	TIMCAL		;Convert time
	BIT	#<TRACE>,.LIFLG	;Trace mode on?
	BNE	1$		;Branch if yes - overrides QUIET mode
	BIT	#<QUIET>,.LIFLG	;Is quiet enabled?
	BNE	2$		;Yes, so don't print anything
1$:	.PRINT	#DELMSG		;Print delaying message
2$:	.TWAIT	#EMTBLK,#TIMBLK	;issue the TWAIT.
	BIT	#<TRACE>,.LIFLG	;Trace mode on?
	BNE	3$		;Branch if yes - overrides QUIET mode
	BIT	#<QUIET>,.LIFLG	;Is quiet enabled?
	BNE	4$		;Yes, don't print the message.
3$:	.PRINT	#CONMSG		;Print the continue message
4$:	JMP	INDRD		;Get the next command line.

	.DSABL	LSB
	.SBTTL	TIMCAL - Convert specified time argument to ticks

;+
;TIMCAL
;The following subroutine converts a string of ASCII numbers to a one word
;binary number.  The string may be either an OCTAL or DECIMAL representation
;(DECIMAL is denoted by a period following the numerical string).  After the
;unit count is recieved, time type (H for hour, M for minute, S for second,
;and T for tick) is tested (R2) for conversion to total ticks.
;
; Call:	CALL	TIMCAL		;Convert time
;
; Input:  R0 -> the start of the ASCII string containing numerical input
;
; Output: R0 -> after last character processed in ASCII buffer.
;	  TIMBLK = High order timer word
;		   Low order timer word
;-
	  
	.ENABL	LSB

TIMCAL::CALL	$GTNUM		;Get unit count in R1, type in R2 (H,M,S,T)
	BCS	2$		;Numeric under- or overflow
	SAVE	<R0,R4>
	MOV	R2,R4		;Get time type
	CMPB	R4,#<'A+40>	;Check if in range of lowercase characters
	BLT	1$		;Branch if no
	CMPB	R4,#<'Z+40>	;Check if beyond high end
	BGT	1$		;Branch if no
	BICB	#40,R4		;Make lowercase character uppercase
1$:	MOV	R1,R3		;Get low order time
	CLR	R2		;And clear high order
	CMPB	R4,#'H		;Hours?
	BEQ	3$		;Branch if yes
	CMPB	R4,#'M		;Minutes?
	BEQ	4$		;Branch if yes
	CMPB	R4,#'S		;Seconds?
	BEQ	5$		;Branch if yes
	CLR	R0		;Clear incase it's high order word
	CMPB	R4,#'T		;Ticks?
	BEQ	6$		;Branch if yes
	CMP	(SP)+,(SP)+	;Clean up
	TRAP	ERSYN		;And display syntax error

2$:	TRAP	ERNOV		;Numeric under- or overflow

;+
;Routine to convert time.
;-

3$:	MOV	#60.,R0		;Convert hours to minutes.
	CALL	$MUL
4$:	MOV	#60.,R0		;Convert minutes to seconds.
	CALL	$MUL
5$:	MOV	TICKS,R0	;Convert seconds to ticks.
	CALL	$MUL
6$:	MOV	R0,TIMBLK	;Store high order timer word
	MOV	R1,TIMBLK+2	;Store low order timer word
	MOV	R3,TIMVAL	;Store the time value for later conversion
	MOVB	R4,TIMUNT	;Store ASCII time unit for later
	RESTOR	<R4,R0>
	RETURN

	.DSABL	LSB
	.SBTTL	ENABLE/DISABLE directive entrys

	.ENABL	LSB

ENABL:: MOV	PC,-(SP)	;Set action non-zero for enable
	BR	10$		;Go do common setup

DSABL:: CLR	-(SP)		;Set action zero for disable
10$:	MOVB	MAP,SPSEXS+SEVAL;Clear <EXSTAT>
	CLR	TMPFLG		;Clear temporary flag word
	CLR	TMPFL2		;Both of them
20$:	CALL	$GNBLK		;Get next non-blank character
	BCS	50$		;Branch if error
	CALL	CHK1		;Check list for valid mode specification
	BCS	50$		;Syntax error
	BIS	R1,@R3		;Set associated bit
	CMP	R3,#TMPFLG	;Is it in the first flag word?
	BNE	40$		;Branch if not
	BIT	#<DATEX>,R1
	BEQ	40$
	CLR	R5		;Clear default - data file indicator
	TST	@SP		;Enable activity?
	BEQ	30$		;Branch if no ENDAT properly set
	CALL	GDFDB		;Get data file FDB
	BCS	150$		;Branch on error
30$:	MOV	R5,ENDAT	;Set up default - data file indicator
	TST	@SP		;ENABLE or DISABLE?
	BNE	40$		;ENABLE
	CALL	$GNBLK		;Get next non-blank character
	BCS	60$		;End of line, now make special checks
	CMPB	#<LB>,R2	;Pound sign?
	BNE	150$		;Bad file number
	TSTB	(R0)+		;Point past supposed number
40$:	CALL	$GNBLK		;Get next non-blank character
	BCS	60$		;End of line, now make special checks
	CMPB	#<COMMA>,R2	;Comma?
	BEQ	20$		;Branch if yes, possibly more
50$:	TST	(SP)+		;Clean stack
	TRAP	ERSYN		;Syntax error

60$:	MOV	TMPFLG,R2	;Set up temp flag in register
	BIT	#<DATEX>,R2	;Data flag set?
	BEQ	70$		;Branch if not
	CMP	#<DATEX>,R2	;Is this the only bit set?
	BNE	50$		;If not error
70$:	BIT	#<TIMOUT>,R2	;Is it the timeout option?
	BEQ	80$		;Branch if no
	TST	@SP		;Enable or Disable?
	BEQ	80$		;Disable
	TSTB	TIMSUP		;Is this a valid command at this time?
	BNE	80$		;Yes, give no warning message
	MOVB	MAP+1,SPSEXS+SEVAL;Give WARNING status
80$:	BIT	#<QUIET>,R2	;Quiet mode set?
	BEQ	90$		;Branch if no
	TST	@SP		;Enable or Disable action?
	BNE	90$		;Enable
	.RCTRLO			;Reset CTRL/O
90$:	BIT	#<ABORT>,R2	;Is it the CONTRL/C option?
	BEQ	110$		;Branch if not
	MOV	@#SYSPTR,R0	;Point to start of RMON
	BIT	#<GSCCA$>,$CNFG2(R0) ;Is GSCCA support sysgenned?
	BNE	100$		;Branch if so
	MOVB	MAP+1,SPSEXS+SEVAL;Give WARNING status and continue
100$:	BISB	#CC$IND,$INDIR(R0)	;Assume Disable
	TST	@SP		;Enable or Disable?
	BEQ	110$		;Branch if disable
	BICB	#CC$IND,$INDIR(R0)	;Enable CONTROL/c
110$:	TST	(SP)+		;Final check for ENABLE/DISABLE
	BEQ	130$		;Disable activity

; .ENABLE appropriate mode bits

	BIS	R2,.LIFLG	;Set mode bits in primary flag word

	BIT	#<TYPAHD>,TMPFL2	; enabling TYPEAHEAD?
	BEQ	120$			; branch if not
	BIT	#<TYPAHD>,.LFLG2	; was TYPEAHEAD enabled before?
	BNE	120$			; skip if it was

	CALL	FLUSH			; Flush terminal input characters

120$:	BIS	TMPFL2,.LFLG2	;And in second flag word
	BR	140$		;Exit

; .DISABLE appropriate mode bits

130$:	BIC	R2,.LIFLG	;Disable modes
	BIC	TMPFL2,.LFLG2	;And in second flag word
140$:	JMP	INDRD		;Go get next command

150$:	TRAP	ERIFN		;Bad file number

	.DSABL	LSB

	ROUNDUP			;Check for overflow and roundup

	.END