.MCALL	.MODULE
.MODULE	IDELET,VERSION=04,COMMENT=<IDELET/SYSLIB>,IDENT=No,LIB=Yes

; Copyright (c) 1998 by Mentec, Inc., Nashua, NH.
; All rights reserved
;
; This software is furnished under a license for use only on a
; single computer system and  may  be  copied  only  with  the
; inclusion of the above copyright notice.  This software,  or
; any other copies thereof, may not be provided  or  otherwise
; made available to any other person except for  use  on  such
; system and to one who agrees to these license  terms.  Title
; to  and  ownership of the software shall at all times remain
; in Mentec, Inc.
;
; The information in this document is subject to change without
; notice and should not be construed as a commitment by Digital
; Equipment Corporation, or Mentec, Inc.
;
; Digital and Mentec  assume  no  responsibility for the use or
; reliability of its software on equipment which is not supplied
; by Digital  or Mentec,  and listed  in the  Software  Product
; Description.
	.SBTTL	Module Declarations

	.NLIST
	.ENABL	LC
	.DSABL	GBL
	.NLIST	CND
	.LIST
; ++
; FACILITY:
;
;    RT-11 System Subroutine Library
;
; ENVIRONMENT:
;
;    This routine can be used by any job running in a single-job
;    or  multi-job  environment,  but  cannot  be  called from a
;    completion or interrupt service routine. It uses "TRAP"  to
;    provide error processing.
;
; INCLUDE FILES:
;

	; SYSMAC.SML		; RT-11 system macro library

	.MCALL	.DELETE		; DELETE programmed request

;
; EXTERNAL REFERENCES:
;

	.GLOBL	$ERRP0		; Entry point to EMT error conversion routine
	.GLOBL	$NXADR		; Entry point to next address routine
	.GLOBL	$NXVAL		; Entry point to next value routine
	.GLOBL	$SYSLB		; Include system library work area
	.WEAK	$MSARG		; Trap code for missing argument
	.SBTTL	IDELET - Fortran-callable Routine

; ++
; FUNCTIONAL DESCRIPTION:
;
;    The IDELET function deletes a named file from the specified device.
;    
; CALLING SEQUENCE:
;
;    i = IDELET( chan, dblk [,seqnum] )
;
; INPUT PARAMETERS:
;
;    R5	     -	address of IDELET's argument block
;
;    0(R5)   -  argument count of IDELET call
;    2(R5)   -  address of number of channel to use for file deletion
;    4(R5)   -  address of four-word Radix-50 descriptor of file to delete
;    6(R5)   -  address of file no. for cassette  operations; if argument
;	        is omitted, value is defaulted to 0
;
; OUTPUT PARAMETERS:
;
;    R0	     -  file deletion status
;
; RETURNED FUNCTION VALUE: 
;
;    0       -	normal return; file deleted
;    1	     -	channel ('chan') is already opened
;    2	     -	file specified was not found
;    3	     -	specified device in use
;    4	     -	file is protected and cannot be deleted
;
; --

	.PSECT	SYS$I

DELET::	
IDELET::	
	MOV	(R5)+,R4	; R4(low byte) <- argument count
	CALL	$NXVAL		; Get 'chan' argument

	BCS	ERR		; If CS, error - 'chan' wasn't  supplied
	MOV	R0,R3		; R3 <- channel no. to use for .DELETE

	CALL	$NXADR		; Get -> 'dblk' argument
	BCS	ERR		; If CS, error - 'dblk' wasn't  supplied

	MOV	R0,R2		; R2 <- addrss of descriptor of file to delete

	CLR	R0		; Default 'seqnum' to 0 - in case it's omitted
	CALL	$NXVAL		; Get 'seqnum' argument
	MOV	R0,-(SP)	; Store 'seqnum' in DELETE's argument block


	CMP	-(SP),-(SP)	; Allocate remaining space required for DELETE's
				; argument block
	.DELETE	SP,R3,R2	; Delete named file from specified device
	CALL	$ERRP0		; Get and convert any errors (status in R0)
	ADD	#6,SP		; Purge stack of argument block
	RETURN			; Return to caller with status in R0

ERR:	TRAP	$MSARG		; Handle any missing arguments in call
	RETURN		

	.END