.MCALL	.MODULE
.MODULE	ICMKT,VERSION=04,COMMENT=<ICMKT/SYSLIB>,IDENT=No,LIB=Yes

; Copyright (c) 1998 by Mentec, Inc., Nashua, NH.
; All rights reserved
;
; This software is furnished under a license for use only on a
; single computer system and  may  be  copied  only  with  the
; inclusion of the above copyright notice.  This software,  or
; any other copies thereof, may not be provided  or  otherwise
; made available to any other person except for  use  on  such
; system and to one who agrees to these license  terms.  Title
; to  and  ownership of the software shall at all times remain
; in Mentec, Inc.
;
; The information in this document is subject to change without
; notice and should not be construed as a commitment by Digital
; Equipment Corporation, or Mentec, Inc.
;
; Digital and Mentec  assume  no  responsibility for the use or
; reliability of its software on equipment which is not supplied
; by Digital  or Mentec,  and listed  in the  Software  Product
; Description.

	.NLIST
	.ENABL	LC
	.DSABL	GBL
	.NLIST	CND
	.LIST
; ++
; FACILITY:
;
;    RT-11 System Subroutine Library
;
; ENVIRONMENT:
;
;    This routine can be used by any job running in a single-job
;    (SYSGENed with timer suuport) or multi-job environment.  It
;    uses "TRAP" to provide error processing.
;
; --
	.SBTTL	Module Declarations

;
; INCLUDE FILES:
;

	; SYSMAC.SML		; RT-11 system macro library.

	.MCALL	.CMKT		; CMKT programmed request.

;
; EXTERNAL REFERENCES:
;
	.GLOBL	$SYSLB		; Include system library work area.
	.GLOBL	$ERRP0		; Entry point to EMT error conversion routine.
	.GLOBL	$NXADR		; Entry point to next address routine.
	.GLOBL	$NXVAL		; Entry point to next value routine.
	.WEAK	$MSARG		; Trap code for missing argument
	.SBTTL	ICMKT - Fortran-callable Routine

; ++
; FUNCTIONAL DESCRIPTION:
;
;    The ICMKT function cancels one or more scheduling requests.
;    
; CALLING SEQUENCE:
;
;    i = ICMKT( id [,itime] )
;
; INPUT PARAMETERS:
;
;    R5	     -	address of ICMKT's argument block
;
;    0(R5)   -  argument count of ICMKT call
;    2(R5)   -  address of mark time request id to cancel.  If 'id' is 0,
;		all non-system mark time requests (1-176777) for  issuing
;		job are canceled
;    4(R5)   -  address of two-word area in which monitor returns  amount
;		of time (clock ticks)  remaining in canceled request.  If
;		4(R5) is 0 or -1 , no value is returned.
;
; OUTPUT PARAMETERS:
;
;    R0	     -	mark time request cancel status
;
;    itime   -	two-word area loaded with remaining time in canceled request
;		word 1  -  high-order time remaining
;		word 2  -  low-order time remaining
;
; ROUTINE VALUE:
;
;    0       -	no error canceling mark time request(s)
;    1	     -	'id' argument was not zero and no scheduling request with
;		that identification could be found for this job
;
; --

	.PSECT	SYS$I

CMKT::				
ICMKT::				
	MOV	(R5)+,R4	; R4(low byte) <- argument count.
	CALL	$NXVAL		; Get 'id' argument
	BCS	ERR		; If CS, error - 'chan' wasn't  supplied

	MOV	R0,R3		; R3 <- id of mark time request to cancel
	CLR	R0		; Default 'itime' to 0 - in case it's omitted
	CALL	$NXADR		; Get -> 'itime' argument
	MOV	R0,R2		; R2 <- address of area to get time remaining

	SUB	#6,SP		; Allocate space for CMKT's argument block
	.CMKT	SP,R3,R2	; Cancel specified mark time requests
	CALL	$ERRP0		; Get and convert any errors (status in R0)
	ADD	#6,SP		; Purge stack of argument block
	RETURN			; Return to caller with status in R0

ERR:	TRAP	$MSARG		; Handle any missing arguments in call
	RETURN			

	.END