.MCALL	.MODULE
.MODULE	IABTIO,VERSION=04,COMMENT=<IABTIO/SYSLIB>,IDENT=No,LIB=Yes

; Copyright (c) 1998 by Mentec, Inc., Nashua, NH.
; All rights reserved
;
; This software is furnished under a license for use only on a
; single computer system and  may  be  copied  only  with  the
; inclusion of the above copyright notice.  This software,  or
; any other copies thereof, may not be provided  or  otherwise
; made available to any other person except for  use  on  such
; system and to one who agrees to these license  terms.  Title
; to  and  ownership of the software shall at all times remain
; in Mentec, Inc.
;
; The information in this document is subject to change without
; notice and should not be construed as a commitment by Digital
; Equipment Corporation, or Mentec, Inc.
;
; Digital and Mentec  assume  no  responsibility for the use or
; reliability of its software on equipment which is not supplied
; by Digital  or Mentec,  and listed  in the  Software  Product
; Description.
	.SBTTL	Module Declarations

	.NLIST
	.ENABL	LC
	.DSABL	GBL
	.NLIST	CND
	.LIST
; ++
; FACILITY:
;
;    RT-11 System Subroutine Library
;
; ENVIRONMENT:
;
;    This routine can be used by any job running in a single-job
;    or   multi-job  environment,  but  cannot  be  called  from
;    completion  routines.  It  uses  "TRAP"  to  provide  error
;    processing.
;
; INCLUDE FILES:
;

	; SYSMAC.SML		; RT-11 system macro library.

	.MCALL	.ABTIO		; ABTIO programmed request.

;
; EXTERNAL REFERENCES:
;

	.GLOBL	$ERRM0		; Entry point to EMT error conversion routine.
	.GLOBL	$NXVAL		; Entry point to next value routine.
	.GLOBL	$SYSLB		; Include system library work area.
	.WEAK	$MSARG		; Trap code for missing argument
	.SBTTL	IABTIO - Fortran-callable Routine

; ++
; FUNCTIONAL DESCRIPTION:
;
;    The IABTIO routine aborts i/o on a specified channel.
;    
; CALLING SEQUENCE:
;
;    i = IABTIO( chan )
;
; INPUT PARAMETERS:
;
;    R5	     -	address of IABTIO's argument block
;
;    0(R5)   -	argument count of IABTIO call
;    2(R5)   -	address of number of channel to abort i/o
;
; OUTPUT PARAMETERS:
;
;    R0	     -	abort i/o status
;
; ROUTINE VALUE:
;
;    0	     -	no error aborting i/o
;
; --

	.PSECT	SYS$I

ABTIO::				; Entry point to IABTIO routine.
IABTIO::
	MOV	(R5)+,R4	; R4 <- argument count.

	CALL	$NXVAL		; Get 'chan' argument; it's returned in R0
	BCS	ERR		; If CS, error - 'chan' argument wasn't
				; supplied; report missing argument in call.
	MOVB	R0,R3		; R3 <- number of channel to abort; isolates
				; chan no. in low byte of 'chan' for .ABTIO.
	.ABTIO	R3		; Abort all i/o on caller-specified channel.
	CALLR	$ERRM0		; Get and convert any errors (status in R0)
				; and return to caller with status in R0.

ERR:	TRAP	$MSARG		; Handle any missing arguments in call
	RETURN			
	.END